> Private Sub Command3_Click()
> 'delete from list box2
> Dim rst As DAO.Recordset
> Set rst = CurrentDb.OpenRecordset("SELECT * FROM account WHERE
> 'account type' = '" & Me.list2 & "'")
> rst.Delete
> Me.list2.Requery

> End Sub

>> Private Sub Command3_Click()
>> 'delete from list box2
>> Dim rst As DAO.Recordset
>> Set rst = CurrentDb.OpenRecordset("SELECT * FROM account WHERE
>> 'account type' = '" & Me.list2 & "'")
>> rst.Delete
>> Me.list2.Requery

>> End Sub

>Your SQL statement incorrectly puts quotes around the [account type] field.
>If you are going to do it via a recordset like that, this would be better:

>'------ start of amended code #1 ------
>Private Sub Command3_Click()

>    Dim rst As DAO.Recordset

>    With Me.list2

>        If Not IsNull(.Value) Then

>            Set rst = CurrentDb.OpenRecordset( _
>                "SELECT * FROM account WHERE [account type] = '" & _
>                .Value & "'")

>            rst.Delete
>            rst.Close

>        End If

>        .Requery

>    End With

>End Sub
>'------ end of amended code #1 ------

>However, that is not the best way to do it.  This would be better:

>'------ start of amended code #2 ------
>Private Sub Command3_Click()

>    With Me.list2

>        If Not IsNull(.Value) Then

>            CurrentDb.Execute _
>                "DELETE FROM account WHERE [account type] = '" & _
>                    .Value & "'", _
>                dbFailOnError

>        End If

>        .Requery

>    End With

>End Sub
>'------ end of amended code #2 ------

> I agree the [ ] are better than what was there before, but the real
> issue with the Recordset approach is that it does not test for EOF:
> set rst = CurrentDB.OpenRecordset(...)
> if rst.EOF then
>  Msgbox "Alarm: No record found. Unable to delete unfound record!"
> else
>  rst.Delete ...